mirror of
https://github.com/spalencsar/bearhub.git
synced 2026-07-06 20:34:16 +02:00
002b5c839e
Use tag-specific tarball name bearhub-0.10.7-bearhub.6.tar.gz so makepkg and AUR helpers do not reuse an outdated bearhub-0.10.7.tar.gz from cache. Ignore makepkg artifacts under packaging/aur/.
49 lines
1.6 KiB
Bash
49 lines
1.6 KiB
Bash
pkgname=bearhub
|
|
pkgver=0.10.7
|
|
pkgrel=10
|
|
pkgdesc="Arch-first package manager hub (community-maintained fork of bauh)"
|
|
arch=('any')
|
|
url="https://github.com/spalencsar/bearhub"
|
|
license=('ZLIB')
|
|
depends=(
|
|
'python'
|
|
'python-pyqt5'
|
|
'python-requests'
|
|
'python-colorama'
|
|
'python-pyyaml'
|
|
'python-dateutil'
|
|
)
|
|
optdepends=(
|
|
'python-lxml: web application support'
|
|
'python-beautifulsoup4: web application support'
|
|
'flatpak: flatpak support'
|
|
'appimagekit: appimage support'
|
|
)
|
|
makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
|
|
provides=('bearhub' 'bauh')
|
|
conflicts=('bearhub-git' 'bauh' 'bauh-git')
|
|
_pkgver_tag="${pkgver}-bearhub.6"
|
|
source=("$pkgname-${_pkgver_tag}.tar.gz::$url/archive/refs/tags/${_pkgver_tag}.tar.gz")
|
|
sha256sums=('6fa9dfbff1cdb86a5eb837275170434069d320fd3072324ca9f4eb4beea92a04')
|
|
|
|
build() {
|
|
cd "$srcdir/$pkgname-${pkgver}-bearhub.6"
|
|
python -m build --wheel --no-isolation
|
|
}
|
|
|
|
package() {
|
|
cd "$srcdir/$pkgname-${pkgver}-bearhub.6"
|
|
|
|
sed -i 's|^Exec=/usr/bin/bearhub$|Exec=env QT_QPA_PLATFORM=xcb /usr/bin/bearhub|' "bearhub/desktop/bearhub.desktop"
|
|
sed -i 's|^Exec=/usr/bin/bearhub-tray$|Exec=env QT_QPA_PLATFORM=xcb /usr/bin/bearhub-tray|' "bearhub/desktop/bearhub_tray.desktop"
|
|
|
|
python -m installer --destdir="$pkgdir" dist/*.whl
|
|
|
|
install -Dm644 "bearhub/desktop/bearhub.desktop" \
|
|
"$pkgdir/usr/share/applications/bearhub.desktop"
|
|
install -Dm644 "bearhub/desktop/bearhub_tray.desktop" \
|
|
"$pkgdir/usr/share/applications/bearhub-tray.desktop"
|
|
install -Dm644 "bearhub/view/resources/img/logo.svg" \
|
|
"$pkgdir/usr/share/icons/hicolor/scalable/apps/bearhub.svg"
|
|
}
|